SPICE Modeling and amp building.

[Shrapnel]

Who all here uses SPICE modeling to do "theoretical" testing on their designs. Reason I ask is I got LTSpiceIV (SwitcherCad III update) and models for most of the usual tubes (including output) but alas, I don't find any models for a 7591, and From what spec sheets I do have (JJ's specs has plate curves) I can't figure out all the data I need to help put together a definition of that tube. So, unless someone has a model for one, that so far I can't find, I need to figure out if I have all the pieces to the puzzle, and then how to place them together to make me a model.

[FYL]

From an old archive:


****
*
*  R McLean 9 January 2005
*
* 7591 pentode
* parameter extraction, from data sheets, 9 January 2005
* grid current not modeled
****
*
.SUBCKT 7591 A S G K
+ PARAMS: Ex=1.3215754205161 Kg1=972.600855246932 Kp=97.9392597291279 Kvb=25.0367202802361 Mu=16.7208998295801
+ Exd=2.78742077218546 Kd=159498.449500327 Ks=1.89047582270854  Kg=0.00189539610643784
+ CCG=10.0P CPG1=0.25P CCP=5.0P

Eat   at   0   Value={limit(0.636*ATAN(limit(V(A,K),0,2000)/KVB),0,1)} ; arctangent shaping
Eme   me   0   VALUE={PWR(LIMIT(V(A,K),0,2000),EXD)/KD} ; diode line
Egs   gs   0   VALUE= {V(S,K)/KP*LOG(1+EXP((1/MU+V(G,K)/V(S,K))*KP))} ; effective voltage
Egs2   gs2   0   VALUE={(PWR(V(gs),EX)+PWRS(V(gs),EX))/(KG1*0.636)} ; total space current
G1   A   K   VALUE={LIMIT(V(gs2)*V(at),0,V(me))} ; plate current
Escrn   sc   0   VALUE={KS*V(gs2)*(1.1-V(at))} ; reverse arctan shaping for screen current
G2        S        K   VALUE={Limit(V(sc),0,10)*LIMIT(V(S,K),0,10)/10} ; screen current
* no grid current data available so comment out the grid current line
*G3   G   K   VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*(1.25-V(at))*KG}  ; grid current
C1   G   K   {CCG}   ; CATHODE-GRID 1
C2   A   G   {CPG1}  ; GRID 1-PLATE
C3   A   K   {CCP}   ; CATHODE-PLATE
.ENDS 7591

[Shrapnel]

thanks FYL. I appreciate it.